plugins {
    id("java")
    id("io.freefair.lombok") version "9.2.0" apply false
}

group = "de.kentoj.scrow"
version = "1.0.0"

repositories {
    mavenCentral()
    scrowRepo(this)
}

subprojects {
    apply(plugin = "java")
    apply(plugin = "io.freefair.lombok")

    version = rootProject.version

    java {
        withSourcesJar()
        withJavadocJar()
    }

    tasks.withType<Javadoc>().configureEach {
        (options as StandardJavadocDocletOptions).addStringOption("Xdoclint:all,-missing", "-quiet")
    }

    repositories {
        mavenCentral()
        maven("https://hub.spigotmc.org/nexus/content/repositories/snapshots/") {
            name = "spigotmc-repo"
        }
        scrowRepo(this)
    }

    dependencies {
        // https://mvnrepository.com/artifact/org.jetbrains/annotations
        implementation("org.jetbrains:annotations:26.0.2-1")

        // https://projectreactor.io/docs/core/release/reference/gettingStarted.html
        implementation(platform("io.projectreactor:reactor-bom:2025.0.3"))
        implementation("io.projectreactor:reactor-core")

        // https://mvnrepository.com/artifact/com.google.guava/guava
        implementation("com.google.guava:guava:33.5.0-jre")

        // https://www.mongodb.com/docs/languages/java/reactive-streams-driver/current/get-started/download-and-install/
        implementation(platform("org.mongodb:mongodb-driver-bom:5.6.1"))
        implementation("org.mongodb:mongodb-driver-reactivestreams")

        // https://mvnrepository.com/artifact/org.postgresql/r2dbc-postgresql
        // TODO remove or fully switch to postgres
        implementation("org.postgresql:r2dbc-postgresql:1.1.1.RELEASE")
        // https://mvnrepository.com/artifact/org.springframework.data/spring-data-r2dbc
        implementation("org.springframework.data:spring-data-r2dbc:4.1.0-RC1")
        // https://mvnrepository.com/artifact/io.r2dbc/r2dbc-pool
        implementation("io.r2dbc:r2dbc-pool:1.0.2.RELEASE")
    }
}