plugins {
    id("java")
    alias(libs.plugins.shadow)
    alias(libs.plugins.scrow.basedependencies)
    alias(libs.plugins.scrow.database)
}

group = "de.kentoj.scrow"

dependencies {
    implementation(project(":core-velocity-api"))
    annotationProcessor(libs.velocity.api)
    implementation(libs.nats)
    implementation(libs.postgres)
}

tasks.build {
    dependsOn("shadowJar")
}

val generateBuildInfo by tasks.registering {
    val outputDir = layout.buildDirectory.dir("generated/sources/buildInfo")
    outputs.dir(outputDir)
    doLast {
        val file = outputDir.get()
            .file("de/kentoj/scrow/generated/BuildInfo.java")
            .asFile
        file.parentFile.mkdirs()
        file.writeText(
            """
            package de.kentoj.scrow.generated;
            public final class BuildInfo {
                private BuildInfo() {}
                public static final String VERSION = "${project.version}";
            }
            """.trimIndent()
        )
    }
}

sourceSets.main {
    java.srcDir(generateBuildInfo)
}