plugins {
    id("java")
    id("com.gradleup.shadow") version "9.2.0"
}

group = "de.kentoj.scrow"

repositories {
    mavenCentral()
    maven {
        name = "papermc"
        url = uri("https://repo.papermc.io/repository/maven-public/")
    }
}

dependencies {
    implementation(project(":core-velocity-api"))

    // https://docs.papermc.io/velocity/dev/creating-your-first-plugin/
    annotationProcessor("com.velocitypowered:velocity-api:3.5.0-SNAPSHOT")

    // https://mvnrepository.com/artifact/com.github.ben-manes.caffeine/caffeine
    implementation("com.github.ben-manes.caffeine:caffeine:3.2.4")

    // http://forge.kentoj.de/scrow/-/packages/maven/de.kentoj.scrow:kencommandapi-velocity
    implementation("de.kentoj.scrow:kencommandapi-velocity")
}

val generateBuildInfo by tasks.registering {
    val outputDir = layout.buildDirectory.dir("generated/sources/buildInfo")
    outputs.dir(outputDir)
    doLast {
        val file = outputDir.get()
            .file("de/kentoj/scrow/generated/BuildInfo.java")
            .asFile
        file.parentFile.mkdirs()
        file.writeText(
            """
            package de.kentoj.scrow.generated;
            public final class BuildInfo {
                private BuildInfo() {}
                public static final String VERSION = "${project.version}";
            }
            """.trimIndent()
        )
    }
}
sourceSets.main {
    java.srcDir(generateBuildInfo)
}