val scrowToken = providers.gradleProperty("scrowMavenToken")
    .orElse(providers.environmentVariable("SCROW_MAVEN_TOKEN")).get()

plugins {
    id("java")
    id("io.freefair.lombok") version "9.2.0" apply false
}

group = "de.kentoj.scrow"
version = "1.0-SNAPSHOT"

repositories {
    mavenCentral()
}

subprojects {
    apply(plugin = "java")
    apply(plugin = "io.freefair.lombok")

    java {
        withSourcesJar()
        withJavadocJar()
    }

    tasks.withType<Javadoc>().configureEach {
        (options as StandardJavadocDocletOptions).addStringOption("Xdoclint:all,-missing", "-quiet")
    }

    repositories {
        mavenCentral()
        maven("https://hub.spigotmc.org/nexus/content/repositories/snapshots/") {
            name = "spigotmc-repo"
        }
        maven {
            name = "scrow"
            url = uri("http://forge.kentoj.de/api/packages/scrow/maven")
            isAllowInsecureProtocol = true
            credentials(HttpHeaderCredentials::class) {
                name = "Authorization"
                value = "token $scrowToken"
            }
            authentication {
                create<HttpHeaderAuthentication>("header")
            }
        }
    }

    dependencies {
        // https://mvnrepository.com/artifact/org.jetbrains/annotations
        implementation("org.jetbrains:annotations:26.0.2-1")

        // https://projectreactor.io/docs/core/release/reference/gettingStarted.html
        implementation(platform("io.projectreactor:reactor-bom:2025.0.3"))
        implementation("io.projectreactor:reactor-core")

        // https://mvnrepository.com/artifact/com.google.guava/guava
        implementation("com.google.guava:guava:33.5.0-jre")

        // https://www.mongodb.com/docs/languages/java/reactive-streams-driver/current/get-started/download-and-install/
        implementation(platform("org.mongodb:mongodb-driver-bom:5.6.1"))
        implementation("org.mongodb:mongodb-driver-reactivestreams")
    }
}